plugins {
    id 'fabric-loom' version '1.0-SNAPSHOT'
    id 'maven-publish'
    id 'io.github.juuxel.loom-quiltflower' version '1.7.+'
    id 'me.hypherionmc.cursegradle' version '2.+'
    id "com.modrinth.minotaur" version "2.+"
}

version = project.mod_version
group = project.maven_group

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.

    maven { url = "https://api.modrinth.com/maven" } // LazyDFU, Suggestion Tweaker
    maven { url = "https://maven.terraformersmc.com" } // Mod Menu
    maven { url = "https://maven.shedaniel.me/" } // Cloth Config
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    modLocalRuntime("maven.modrinth:lazydfu:0.1.2") // lazydfu - improves start times
    //modLocalRuntime("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") { exclude(group: "net.fabricmc.fabric-api") } // required for suggestion tweaker
    modLocalRuntime("maven.modrinth:suggestion-tweaker:${project.suggestion_tweaker_version}") // suggestion tweaker - dev QOL, improves command suggestions

    modApi("com.terraformersmc:modmenu:${project.modmenu_version}")

    modApi("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") { exclude(group: "net.fabricmc.fabric-api") } // required for suggestion tweaker
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

def targetJavaVersion = 17
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release = targetJavaVersion
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    archivesBaseName = project.archives_base_name
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}

import com.modrinth.minotaur.dependencies.ModDependency

curseforge {
    if (!file('./CHANGELOG.md').canRead()) { throw new FileNotFoundException("Could not read changelog file") }
    apiKey = project.hasProperty("CURSEFORGE_TOKEN") ? project.CURSEFORGE_TOKEN : ""
    project {
        id = '699839'
        changelog = file('./CHANGELOG.md')
        changelogType = 'markdown'
        releaseType = 'release'
        accepted_minecraft_version.split(",").each {
            addGameVersion it.trim()
        }

        mainArtifact(remapJar) {
            displayName = "${mod_version_friendly}"
            relations {
                requiredDependency 'fabric-api'
                requiredDependency 'cloth-config'
                optionalDependency 'modmenu'
            }
        }
    }
    options {
        //debug = true
        javaVersionAutoDetect = false
        forgeGradleIntegration = false
    }
}

modrinth {
    if (!file('./CHANGELOG.md').canRead()) { throw new FileNotFoundException("Could not read changelog file") }
    token = project.hasProperty("MODRINTH_TOKEN") ? project.MODRINTH_TOKEN : ""
    projectId = '3Ug95SjF'
    versionNumber = "${mod_version}"
    versionName = "${mod_version_friendly}"
    changelog = file('./CHANGELOG.md').text
    uploadFile = remapJar
    accepted_minecraft_version.split(",").each {
        gameVersions.add it.trim()
    }
    loaders = ['fabric', 'quilt']
    dependencies = [
        // https://modrinth.com/mod/fabric-api
        new ModDependency('P7dR8mSH', 'required'),
        // https://modrinth.com/mod/cloth-config
        new ModDependency('9s6osm5g', 'required'),
    ]
    //debugMode = true
}

task publishToModSites {
    publishToModSites.dependsOn modrinth
    publishToModSites.dependsOn curseforge
}